Galileo Computing < openbook > Galileo Computing - Professionelle Bücher. Auch für Einsteiger.
Professionelle Bücher. Auch für Einsteiger.

Inhaltsverzeichnis
1 Einführung
2 Grundlagen
3 Fehlerbehandlung
4 Erweiterte Grundlagen
5 Objektorientierte Programmierung
6 Wichtige Klassen in .NET
7 Weitere Elemente eines Windows-Programms
8 Datenbank-Anwendungen mit ADO.NET
9 Internet-Anwendungen mit ASP.NET
10 Zeichnen mit GDI+
11 Neues in Visual Basic 2008
12 Beispielprojekte
A Installation
B Lösungen der Übungsaufgaben
Stichwort

Download:
- ZIP, ca. 8,4 MB
Buch bestellen
Ihre Meinung?

Spacer
 <<   zurück
Einstieg in Visual Basic 2008 von Thomas Theis
Inkl. zahlreicher Beispiele und Uebungen
Buch: Einstieg in Visual Basic 2008

Einstieg in Visual Basic 2008
geb., mit DVD
442 S., 24,90 Euro
Galileo Computing
ISBN 978-3-8362-1192-5
Online bestellenJetzt online bestellen
* versandkostenfrei in (D) und (A)
Pfeil 7 Weitere Elemente eines Windows-Programms
  Pfeil 7.1 Hauptmenü
    Pfeil 7.1.1 Erstellung des Hauptmenüs
    Pfeil 7.1.2 Code des Hauptmenüs
    Pfeil 7.1.3 Klasse Font
    Pfeil 7.1.4 Schriftart
    Pfeil 7.1.5 Schriftgröße
    Pfeil 7.1.6 Schriftstil
  Pfeil 7.2 Kontextmenü
    Pfeil 7.2.1 Erstellung des Kontextmenüs
    Pfeil 7.2.2 Code des Kontextmenüs
  Pfeil 7.3 Symbolleiste
    Pfeil 7.3.1 Erstellung der Symbolleiste
    Pfeil 7.3.2 Code der Symbolleiste
  Pfeil 7.4 Statusleiste
    Pfeil 7.4.1 Erstellung der Statusleiste
    Pfeil 7.4.2 Code der Symbolleiste
  Pfeil 7.5 Eingabe-Dialogfeld
  Pfeil 7.6 Ausgabe-Dialogfeld
  Pfeil 7.7 Standard-Dialogfelder
    Pfeil 7.7.1 Datei öffnen
    Pfeil 7.7.2 Datei speichern unter
    Pfeil 7.7.3 Verzeichnis auswählen
    Pfeil 7.7.4 Farbe auswählen
    Pfeil 7.7.5 Schrifteigenschaften auswählen


Galileo Computing - Zum Seitenanfang

7.7 Standard-Dialogfelder  Zur nächsten ÜberschriftZur vorigen Überschrift

Es gibt fünf Klassen für Standard-Dialogfelder, mit deren Hilfe alltägliche Aufgaben schnell gelöst werden können: OpenFileDialog, SaveFileDialog, FolderBrowserDialog, ColorDialog und FontDialog.

ShowDialog

Sie haben einige Gemeinsamkeiten, zum Beispiel die Methode Show-Dialog() zur Anzeige des Dialogs und den Rückgabewert, eine Aufzählung des Typs DialogResult. Es existieren aber auch Unterschiede aufgrund der Art des Dialogs bzw. des ermittelten Dialog-Ergebnisses.


Galileo Computing - Zum Seitenanfang

7.7.1 Datei öffnen  Zur nächsten ÜberschriftZur vorigen Überschrift

OpenFileDialog

Ein Objekt der Klasse OpenFileDialog dient zur Auswahl einer Datei, die geöffnet werden soll. Vor dem Öffnen des Dialogfelds kann man unter anderem folgende Einstellungen wählen:

  • InitialDirectory: Verzeichnis, mit dem das Dialogfeld startet

    Filter

  • Filter: verschiedene Gruppen von Datei-Endungen, nach denen die Anzeige gefiltert wird
  • Title: Titelzeile des Dialogfelds

FileName

Das Dialog-Ergebnis (nicht der Rückgabewert) ist ein Dateiname. Dieser wird in der Eigenschaft FileName zur Verfügung gestellt.

Ein Beispiel (in p0703), bei dem nur nach Dateien mit den Endungen »txt« und »doc« gesucht wird:

Abbildung 7.24  Auswahl zum Öffnen einer Datei

Abbildung 7.25  Der eingestellte Dateityp für Texte

Private Sub cmdOpenFileDialog_Click( ... ) Handles ... 
   Dim ofd As New OpenFileDialog 
   ofd.InitialDirectory = "C:\Temp" 
   ofd.Filter = "Tabellen (*.xls)|*.xls| " _ 
      & "Texte (*.txt; *doc)|*.txt;*.doc| " _ 
      & "Alle Dateien (*.*)|*.*" 
   ofd.Title = "Wählen Sie eine Datei zum Öffnen aus" 
   If ofd.ShowDialog() = _ 
         Windows.Forms.DialogResult.OK Then 
      MsgBox("Es wird geöffnet: " & ofd.FileName) 
   Else 
      MsgBox("Abbruch") 
   End If 
End Sub

Zur Erläuterung:

  • Das Objekt ofd der Klasse OpenFileDialog wird erzeugt.
  • Die Eigenschaft InitialDirectory wird (mit einer Zeichenkette) auf ein bestimmtes Verzeichnis eingestellt.
  • Die Eigenschaft Filter bekommt eine Zeichenkette zugewiesen. Diese beinhaltet verschiedene Gruppen von Datei-Endungen und deren Erklärung.
  • Die verschiedenen Gruppen sind durch das Zeichen | voneinander getrennt.
  • Eine Gruppe besteht aus: Erklärung (*.Endung) | *.Endung
  • Besteht eine Gruppe aus mehreren Datei-Endungen (hier z. B. die Gruppe Texte), so werden die Endungen durch Semikolon voneinander getrennt.
  • Die Eigenschaft Title bekommt ebenfalls eine Zeichenkette zugewiesen.

    DialogResultOk

  • Die Methode ShowDialog() zeigt den Dialog an. Es ist wichtig, zu ermitteln, welchen Button der Benutzer gedrückt hat. Deshalb wird der Rückgabewert der Methode ausgewertet. Falls dieser dem Wert von DialogResultOk entspricht, hat der Benutzer den Button Ok betätigt.
  • Wählt der Benutzer eine Datei zum Öffnen aus, die nicht existiert, so erscheint eine Fehlermeldung.
  • In der Eigenschaft FileName steht im Erfolgsfall der ausgewählte Dateiname.
  • Falls eine Datei eingegeben wurde, die nicht existiert, dann erscheint eine Fehlermeldung.

Abbildung 7.26  Fehlermeldung, falls Datei nicht vorhanden


Galileo Computing - Zum Seitenanfang

7.7.2 Datei speichern unter  Zur nächsten ÜberschriftZur vorigen Überschrift

SaveFileDialog

Ein Objekt der Klasse SaveFileDialog dient zur Eingabe oder Auswahl einer Datei, die zum Speichern verwendet werden soll. Wählbare Einstellungen und Dialog-Ergebnis entsprechen im Wesentlichen denen der Klasse OpenFileDialog.

Ein Beispiel (ebenfalls in p0703):

Abbildung 7.27  Auswahl zum Speichern einer Datei

Private Sub cmdSaveFileDialog_Click( ... ) Handles ... 
   Dim sfd As New SaveFileDialog 
   sfd.InitialDirectory = "C:\Temp" 
   sfd.Filter = "Tabellen (*.xls)|*.xls| " _ 
      & "Texte (*.txt; *doc)|*.txt;*.doc| " _ 
      & "Alle Dateien (*.*)|*.*" 
   sfd.Title = "Wählen Sie eine Datei zum Speichern aus" 
   If sfd.ShowDialog() = DialogResult.OK Then 
      MsgBox("Es wird gespeichert unter: " _ 
         & sfd.FileName) 
   Else 
      MsgBox("Abbruch") 
   End If 
End Sub

Abbildung 7.28  Rückfrage, falls Datei bereits vorhanden

Zur Erläuterung:

  • Das Objekt sfd der Klasse SaveFileDialog wird erzeugt.
  • Wählt der Benutzer eine Datei zum Speichern aus, die es bereits gibt, so wird er gefragt, ob er diese überschreiben möchte.

    FileName

  • In der Eigenschaft FileName steht im Erfolgsfall der ausgewählte Dateiname.
  • Falls eine Datei ausgewählt wurde, die bereits existiert, erscheint eine Rückfrage.

Galileo Computing - Zum Seitenanfang

7.7.3 Verzeichnis auswählen  Zur nächsten ÜberschriftZur vorigen Überschrift

FolderBrowser Dialog

Ein Objekt der Klasse FolderBrowserDialog dient zur Auswahl eines Verzeichnisses, das als Basis für weitere Programmabläufe dienen soll. Es kann auch ein neues Verzeichnis erzeugt werden. Vor dem Öffnen des Dialogfelds kann man u. a. folgende Einstellungen wählen:

  • RootFolder: oberstes Verzeichnis, das im Dialogfeld angezeigt wird
  • ShowNewFolderButton: Anzeige eines Buttons, der die Erzeugung eines neuen Verzeichnisses ermöglicht
  • Description: Titelzeile des Dialogfelds

SelectedPath

Das Dialog-Ergebnis ist ein Verzeichnisname. Dieser wird in der Eigenschaft SelectedPath zur Verfügung gestellt.

Ein Beispiel (ebenfalls in p0703):

Abbildung 7.29  Auswahl eines Verzeichnisses

Private Sub cmdFolderBrowserDialog_Click( ... ) _ 
      Handles ... 
   Dim fbd As New FolderBrowserDialog 
   fbd.RootFolder = Environment.SpecialFolder.Desktop 
   fbd.ShowNewFolderButton = False 
   fbd.Description = "Wählen Sie ein Verzeichnis aus" 
   If fbd.ShowDialog() = _ 
         Windows.Forms.DialogResult.OK Then 
      MsgBox("Es wird auf das Verzeichnis: " _ 
         & fbd.SelectedPath & " zugegriffen") 
   Else 
      MsgBox("Abbruch") 
   End If 
End Sub

Zur Erläuterung:

  • Das Objekt fbd der Klasse FolderBrowserDialog wird erzeugt.
  • Als oberstes Verzeichnis des Dialogfelds dient ein Element der Aufzählung SpecialFolder der Klasse Environment, hier ist dies der Desktop.
  • Die Eigenschaft ShowNewFolderButton steht normalerweise auf True. Mit dem Wert False wird verhindert, dass ein neues Verzeichnis erzeugt werden kann.
  • In der Eigenschaft SelectedPath steht im Erfolgsfall der ausgewählte Verzeichnisname.

Galileo Computing - Zum Seitenanfang

7.7.4 Farbe auswählen  Zur nächsten ÜberschriftZur vorigen Überschrift

ColorDialog

Ein Objekt der Klasse ColorDialog dient zur Auswahl einer Farbe, die z. B. einem Steuerelement zugewiesen werden soll.

Color

Das Dialog-Ergebnis ist ein Objekt der Struktur Color; es wird in der Eigenschaft Color zur Verfügung gestellt.

Ein Beispiel (ebenfalls in p0703):

Abbildung 7.30  Auswahl einer Farbe

Private Sub cmdColorDialog_Click( ... ) Handles ... 
   Dim cd As New ColorDialog 
   If cd.ShowDialog() = DialogResult.OK Then 
      lblA.ForeColor = cd.Color 
   Else 
      MsgBox("Abbruch") 
   End If 
End Sub

Zur Erläuterung:

  • Das Objekt cd der Klasse ColorDialog wird erzeugt.
  • In der Eigenschaft Color steht im Erfolgsfall die ausgewählte Farbe. Diese wird hier als Schriftfarbe für das Label übernommen.

Galileo Computing - Zum Seitenanfang

7.7.5 Schrifteigenschaften auswählen  topZur vorigen Überschrift

FontDialog

Ein Objekt der Klasse FontDialog dient zur Auswahl von Schrifteigenschaften, die z. B. einem Steuerelement zugewiesen werden soll. Dialog-Ergebnisse sind:

    Font

  • Ein Objekt der Klasse Font, das in der Eigenschaft Font zur Verfügung gestellt wird.
  • Ein Objekt der Struktur Color, das in der Eigenschaft Color zur Verfügung gestellt wird.

Vor dem Öffnen des Dialogfelds kann man unter anderem folgende Einstellungen wählen:

  • ShowColor: Legt fest, ob auch die Schriftfarbe einstellbar sein soll.
  • MaxSize und MinSize: Stellt die größte und die kleinste wählbare Schriftgröße ein.

Das Dialog-Ergebnis ist ein Objekt der Klasse Font. Dieses wird in der Eigenschaft Font zur Verfügung gestellt.

Ein Beispiel (ebenfalls in p0703):

Abbildung 7.31  Auswahl von Schrifteigenschaften

Private Sub cmdFontDialog_Click( ... ) Handles ... 
   Dim fd As New FontDialog 
   fd.ShowColor = True 
   fd.MinSize = 8 
   fd.MaxSize = 20 
   If fd.ShowDialog() = DialogResult.OK Then 
      lblA.Font = fd.Font 
      lblA.ForeColor = fd.Color 
   Else 
      MsgBox("Abbruch") 
   End If 
End Sub

Zur Erläuterung:

  • Das Objekt fd der Klasse FontDialog wird erzeugt.
  • Die Eigenschaft ShowColor wird auf True gestellt, es können also auch die Farbe der Schrift bzw. der Unterstreichung eingestellt werden.
  • Die wählbare Schriftgröße wird begrenzt auf den Bereich von 8 bis 20.
  • In den Eigenschaften Font und Color stehen im Erfolgsfall die ausgewählten Schrifteigenschaften und die Farbe. Diese werden hier als Schrifteigenschaften für das Label übernommen.


Ihr Kommentar

Wie hat Ihnen das <openbook> gefallen? Wir freuen uns immer über Ihre freundlichen und kritischen Rückmeldungen.






 <<   zurück
  Zum Katalog
Zum Katalog: Einstieg in Visual Basic 2008






Einstieg in Visual Basic 2008
bestellen
 Ihre Meinung?
Wie hat Ihnen das <openbook> gefallen?
Ihre Meinung

 Buchtipps
Zum Katalog: Visual Basic 2008






 Visual Basic 2008


Zum Katalog: Einstieg in Visual C++ 2008






 Einstieg in
 Visual C++ 2008


Zum Katalog: Einstieg in Visual C# 2008






 Einstieg in
 Visual C# 2008


Zum Katalog: Visual C# 2008






 Visual C# 2008


Zum Katalog: Visual C# - Video-Training






 Visual C# -
 Video-Training


Zum Katalog: Einstieg in PHP 5 und MySQL 5






 Einstieg in PHP 5
 und MySQL 5


 Shopping
Versandkostenfrei bestellen in Deutschland und Österreich
InfoInfo





Copyright © Galileo Press 2008
Für Ihren privaten Gebrauch dürfen Sie die Online-Version natürlich ausdrucken. Ansonsten unterliegt das <openbook> denselben Bestimmungen, wie die gebundene Ausgabe: Das Werk einschließlich aller seiner Teile ist urheberrechtlich geschützt. Alle Rechte vorbehalten einschließlich der Vervielfältigung, Übersetzung, Mikroverfilmung sowie Einspeicherung und Verarbeitung in elektronischen Systemen.


[Galileo Computing]

Galileo Press, Rheinwerkallee 4, 53227 Bonn, Tel.: 0228.42150.0, Fax 0228.42150.77, info@galileo-press.de